File:Q tails (serif) pie chart.svg
Original file (SVG file, nominally 650 × 350 pixels, file size: 62 KB)
Captions
Contents
Data
[edit]From Identifont.[1] See also w:en:User:Psiĥedelisto/Q_tails.
type serif sans Meets bowl 3363 4521 Bisecting 1461 2719 “2” shape 304 428 Outside bowl 271 397 Inside bowl only 129 220
Summary
[edit]DescriptionQ tails (serif) pie chart.svg |
English: The code that generated this image is based on only lightly modified code from this StackOverflow answer by user "vagoberto". The code is licensed under the terms of the Creative Commons Attribution-ShareAlike 3.0 Unported license. |
Date | |
Source | Own work |
Author | Psiĥedelisto |
SVG development InfoField | |
Source code InfoField | Gnuplot code# terminal
set terminal svg size 650,350 enhanced font 'Liberation Sans, Helvetica, Arial, sans-serif,10'
set output 'qtails-serif.svg'
set title 'Q tails (serif)' font "Liberation Sans Bold,16"
filename = 'qtails.csv'
rowi = 1
rowf = 7
# obtain sum(column(2)) from rows `rowi` to `rowf`
set datafile separator '\t'
stats filename u 2 every ::rowi::rowf noout prefix "A"
# rowf should not be greater than length of file
rowf = (rowf-rowi > A_records - 1 ? A_records + rowi - 1 : rowf)
angle(x)=x*360/A_sum
percentage(x)=x*100/A_sum
# circumference dimensions for pie-chart
centerX=0
centerY=0
radius=1
# label positions
yposmin = 0.0
yposmax = 0.95*radius
xpos = 1.5*radius
ypos(i) = yposmax - i*(yposmax-yposmin)/(1.0*rowf-rowi)
#-------------------------------------------------------------------
# now we can configure the canvas
set style fill solid 1 # filled pie-chart
unset key # no automatic labels
unset tics # remove tics
unset border # remove borders; if some label is missing, comment to see what is happening
set size ratio -1 # equal scale length
set xrange [-radius:2*radius] # [-1:2] leaves space for labels
set yrange [-radius:radius] # [-1:1]
#-------------------------------------------------------------------
pos = 0 # init angle
colour = 0 # init colour
# 1st line: plot pie-chart
# 2nd line: draw colored boxes at (xpos):(ypos)
# 3rd line: place labels at (xpos+offset):(ypos)
plot filename u (centerX):(centerY):(radius):(pos):(pos=pos+angle($2)):(colour=colour+1) every ::rowi::rowf w circle lc var,\
for [i=0:rowf-rowi] '+' u (xpos):(ypos(i)) w p pt 5 ps 4 lc i+1,\
for [i=0:rowf-rowi] filename u (xpos):(ypos(i)):(sprintf('%.2f%% %s', percentage($2), stringcolumn(1))) every ::i+rowi::i+rowi w labels left offset 3
|
Licensing
[edit]This file is made available under the Creative Commons CC0 1.0 Universal Public Domain Dedication. | |
The person who associated a work with this deed has dedicated the work to the public domain by waiving all of their rights to the work worldwide under copyright law, including all related and neighboring rights, to the extent allowed by law. You can copy, modify, distribute and perform the work, even for commercial purposes, all without asking permission.
http://creativecommons.org/publicdomain/zero/1.0/deed.enCC0Creative Commons Zero, Public Domain Dedicationfalsefalse |
- ↑ 3: $ style. Identifont. Retrieved on 2017-02-02. To get the numbers in the table, click Question 1 (serif or sans-serif?) or Question 2 (Q shape) and change the value. They appear under X possible fonts.
File history
Click on a date/time to view the file as it appeared at that time.
Date/Time | Thumbnail | Dimensions | User | Comment | |
---|---|---|---|---|---|
current | 02:33, 3 February 2017 | 650 × 350 (62 KB) | Psiĥedelisto (talk | contribs) | User created page with UploadWizard |
You cannot overwrite this file.
File usage on Commons
There are no pages that use this file.
File usage on other wikis
The following other wikis use this file:
- Usage on en.wikipedia.org
- Usage on ml.wikipedia.org
Metadata
This file contains additional information such as Exif metadata which may have been added by the digital camera, scanner, or software program used to create or digitize it. If the file has been modified from its original state, some details such as the timestamp may not fully reflect those of the original file. The timestamp is only as accurate as the clock in the camera, and it may be completely wrong.
Short title | Q tails |
---|---|
Image title | Produced by GNUPLOT 5.0 patchlevel 5 |
Width | 650 |
Height | 350 |